問(wèn)：
您好，腳本專家！如何從文本文件中刪除所有重復(fù)行？

-- SW

答：
您好，SW。您知道，成為一名腳本專家便意味著開始永無(wú)止境地尋找給定問(wèn)題的最終解決方案。（或者至少在我們的經(jīng)理問(wèn)為什么我們似乎從未真正完成什么時(shí)，我們是這么告訴他的：“老板，永無(wú)止境的尋找過(guò)程需要時(shí)間！”）這就是為什么我們很高興看到您的問(wèn)題的原因。不久前 我們回答了一個(gè)關(guān)于從文本文件中刪除重復(fù)名字的類似問(wèn)題。我們想到的解決方案十分簡(jiǎn)單而且效果不錯(cuò)；只是我們不確定那是最佳解決方案。現(xiàn)在，很感謝您的問(wèn)題，我們可以再次嘗試解決這一問(wèn)題。至于此解決方案是否比我們之前提供的更好/更快/更方便，還是由您來(lái)決定吧。

首先，假定您有一個(gè)文本文件，其中每一行都表示一條單獨(dú)的記錄。這似乎不太可能，但也許您的文件類似如下：

This is one of the lines in the text file.
This is one of the lines in the text file.
This is another line in the text file.
This is one of the lines in the text file.
This is yet another line in the text file.
This is another line in the text file.
This is another line in the text file.
This is one of the lines in the text file.

您需要一個(gè)可以除去所有重復(fù)行并提供類似以下輸出的腳本：

This is one of the lines in the text file.
This is another line in the text file.
This is yet another line in the text file.

SW，您找對(duì)地方了：

Const adOpenStatic = 3
Const adLockOptimistic = 3
Const adCmdText = &H0001

Set objConnection = CreateObject("ADODB.Connection")
Set objRecordSet = CreateObject("ADODB.Recordset")

strPathToTextFile = "C:\Scripts\"
strFile = "Test.txt"

objConnection.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
      "Data Source=" & strPathtoTextFile & ";" & _
          "Extended Properties=""text;HDR=NO;FMT=Delimited"""

objRecordSet.Open "Select DISTINCT * FROM " & strFile, _
    objConnection, adOpenStatic, adLockOptimistic, adCmdText

Do Until objRecordSet.EOF
    Wscript.Echo objRecordSet.Fields.Item(0).Value   
    objRecordSet.MoveNext
Loop

我們發(fā)現(xiàn)此腳本有些有趣，因?yàn)槲覀兪褂谩癆ctiveX 數(shù)據(jù)對(duì)象”(ADO) 并將此文本文件當(dāng)作數(shù)據(jù)庫(kù)處理。我們不會(huì)花費(fèi)過(guò)多的時(shí)間詳細(xì)說(shuō)明如何將文本文件當(dāng)作數(shù)據(jù)庫(kù)處理；如果您想了解有關(guān)于此的詳細(xì)信息，我們的腳本診所 專欄對(duì)此主題進(jìn)行了深入闡述。現(xiàn)在，要說(shuō)明的只是我們將使用文本文件 C:\Scripts\Test.txt，我們通過(guò)為變量 strPathToTextFile 和 strFile 賦予相應(yīng)值來(lái)表示：

strPathToTextFile = "C:\Scripts\"
strFile = "Test.txt"

那么，這如何能讓我們除去重復(fù)行呢？是這樣的，有一種稱為 Select DISTINCT 的數(shù)據(jù)庫(kù)查詢；利用 Select DISTINCT 可以選擇表格中所有不同的（或唯一的）記錄。假設(shè)您有一個(gè)簡(jiǎn)單的數(shù)據(jù)庫(kù)，其中有以下記錄：


Red
Red
Blue
Red

如果使用 Select DISTINCT 查詢，您將得到一個(gè)只包括唯一記錄的記錄集：

Red
Blue

毫無(wú)疑問(wèn)，您會(huì)想：“哇！返回唯一記錄與刪除重復(fù)記錄簡(jiǎn)直異曲同工?！蔽覀兂姓J(rèn)確實(shí)如此 – 嗯，請(qǐng)等一下：您的想法絕對(duì)正確。我們的文本文件構(gòu)建得就像一個(gè)數(shù)據(jù)庫(kù)表，文本文件中的每行都表示一條記錄中的一個(gè)字段。如果對(duì)此文本文件運(yùn)行 Select DISTINCT 查詢，我們將只得到唯一的行。事實(shí)上，我們將得到如下所示的記錄集：

This is one of the lines in the text file.
This is another line in the text file.
This is yet another line in the text file.

這剛好就是我們希望返回的信息。您為我們指出了這一點(diǎn)，這很好！

檢索記錄集后，我們?cè)偈褂靡韵麓a將唯一的行回顯到屏幕：

Do Until objRecordset.EOF
    Wscript.Echo objRecordset.Fields.Item(0).Value   
    objRecordset.MoveNext
Loop

如果我們?cè)敢?，也可以使?nbsp;FileSystemObject 打開文本文件，然后僅用唯一的行替換現(xiàn)有內(nèi)容；此種方法與從文本文件中刪除所有重復(fù)行效果相同。（如果我們能使用某種 Update 查詢執(zhí)行此操作，效果會(huì)很好，但處理文本文件時(shí)，ADO 卻是只讀的。）

那么，這是從文本文件刪除重復(fù)項(xiàng)（無(wú)論是姓名還是整個(gè)行）的最終結(jié)論嗎？唉，誰(shuí)知道：畢竟，永無(wú)止境的尋找過(guò)程需要時(shí)間?。▽?shí)際上，我們發(fā)現(xiàn)這只需要大約 2 到 3 天。然后，我們便開始覺(jué)得無(wú)聊，又繼續(xù)做其他事情。）