vbs 解析json jsonp的方法

來源：本站原創(chuàng)|時間：2020-01-10|欄目：vb|點擊：次

我收集了三種常見 json jsonp 的格式，因為很多人找我說如何用正則提取某個字符串，我看了下，要么是json，要么是jsonp，
正則簡直浪費，比如那種空間里說說的數據，上百條的信息，你正則個P，而且還有回復里的格式也差不多的，所以最好的方法還是解析。

先來看看常見的三種吧：

酷我音樂用戶信息 json 格式
http://kzone.kuwo.cn/mlog/UserVal?uid=1237357&from=profile
{"work":4,"fans":275,"lp":"{\"id\":1237357,\"username\":\"亂碼\",\"pic\":\"http://img3.kuwo.cn/star/userhead/57/55/1315554310390_1237357m.jpg\"}","art":4,"album":1,"fortune":342402,"article":0,"workVideo":1,"care":195,"workAudio":3,"view":1312997,"playlist":0,"listen":278962,"collect":1}

拍拍手機查詢接口 jsonp 格式
http://virtual.paipai.com/extinfo/GetMobileProductInfo?mobile=13012345678&amount=10000&callname=cb
cb({mobile:'13012345678',province:'重慶',isp:'中國聯(lián)通',stock:'1',amount:'10000',maxprice:'0',minprice:'0'});

搜狐IP信息 js 格式
http://pv.sohu.com/cityjson
var returnCitySN = {"cip": "218.72.14.14", "cid": "330100", "cname": "浙江省杭州市"};

這幾種合適都可以通過 htmlfile 來解析，但是方法稍微有點差異。

先來解析第一種 json 格式的吧。

Set html = CreateObject("htmlfile")
Set http = CreateObject("Msxml2.ServerXMLHTTP")

http.open "GET", "http://kzone.kuwo.cn/mlog/UserVal?uid=1237357&from=profile", False
http.send
strHtml = http.responseText ' 得到數據

Set window = html.parentWindow
window.execScript "var json = " & strHtml, "JScript" ' 解析 json

Set kuwo = window.json ' 獲取解析后的對象
WScript.Echo "訪問量:", kuwo.view, " 財富:", kuwo.fortune

可以得到如下信息。

再來看看 jsonp 的解析，jsonp其實只是多了一個回調函數而已，所以我們自定義一個函數解析他就可以了。

Set html = CreateObject("htmlfile")
Set http = CreateObject("Msxml2.ServerXMLHTTP")
callback = "cb"
url = "http://virtual.paipai.com/extinfo/GetMobileProductInfo?mobile=13012345678&amount=10000&callname=" & callback

http.open "GET", url, False
http.send
strHtml = http.responseText ' 得到數據
' cb({mobile:'13012345678',province:'重慶',isp:'中國聯(lián)通',stock:'1',amount:'10000',maxprice:'0',minprice:'0'});
' <!--[if !IE]>|xGv00|8030d7c308afc4a32846a715ff79e9a3<![endif]-->
' 得到的是這樣的數據，所以要處理下
strHtml = Split(strHtml, vbLf)(0) ' 取第一行
Set window = html.parentWindow
window.execScript "function " & callback & "(o){json=o}", "JScript" ' jsonp 回調函數、
window.execScript strHtml, "JScript" ' 解析 json

Set json = window.json ' 獲取解析后的對象
WScript.Echo json.mobile, json.isp, json.province

可以得到如下信息。

最后看下 js 格式解析，這個是最簡單的，什么都不用做，但是你要知道他的變量名。

Set html = CreateObject("htmlfile")
Set http = CreateObject("Msxml2.ServerXMLHTTP")

http.open "GET", "http://pv.sohu.com/cityjson", False
http.send
strHtml = http.responseText ' 得到數據
' 得到 var returnCitySN = {"cip": "218.72.14.14", "cid": "330100", "cname": "浙江省杭州市"};

Set window = html.parentWindow
window.execScript strHtml, "JScript" ' 解析 js

Set js = window.returnCitySN ' 獲取解析后的對象
WScript.Echo js.cname, js.cip, js.cid

可以得到如下信息

js 格式的是最簡單的，但要注意，變量名是他定的，所以你在獲取解析后的對象那一步，要寫上他的變量名。
json 格式，我們只要給他加上變量名然后解析即可。
jsonp 相對麻煩點，因為要寫一個自定義回調函數。

總的來說，方法差不多，只是解析部分稍微有點不同而已。
用 htmlfile 解析，是不是比正則方便？

以后玩 POST 別再用落伍的 instr+mid 或者正則去解析 html json了， htmlfile 才是王道。

上一篇：vbs qq自動發(fā)信息增強版

欄目：vb

下一篇：使用 iisweb.vbs start 啟動網站的方法

本文標題：vbs 解析json jsonp的方法

本文地址：http://mengdiqiu.com.cn/a1/vb/7270.html

更多vb

欧美大屁股bbbbxxxx,狼人大香伊蕉国产www亚洲,男ji大巴进入女人的视频小说,男人把ji大巴放进女人免费视频,免费情侣作爱视频

vb

vbs 解析json jsonp的方法

您可能感興趣的文章

閱讀排行

本欄相關

隨機閱讀