FileSystemObject對(duì)象被用來(lái)訪問(wèn)服務(wù)器上的文件系統(tǒng)。這個(gè)對(duì)象能夠處理文件、文件夾和目錄路徑。用它來(lái)檢索文件系統(tǒng)信息也是可能的。

下面的代碼創(chuàng)建了一個(gè)文本文件，并寫入了一些文本：

<%
dim fs,fname
set fs=Server.CreateObject("Scripting.FileSystemObject")
set fname=fs.CreateTextFile("c:\test.txt",true)
fname.WriteLine("Hello World!")
fname.Close
set fname=nothing
set fs=nothing
%>

FileSystemObject對(duì)象的屬性和方法如下：

一、屬性

Drives：返回計(jì)算機(jī)上關(guān)于所有Drive對(duì)象的集。
語(yǔ)法：
[drivecoll=]FileSystemObject.Drives

二、方法

Bulidpath：給已存在的路徑增加一個(gè)名字。
CopyFile：從一處復(fù)制一個(gè)或多個(gè)文件到另一處。
CopyFolder：從一處復(fù)制一個(gè)或多個(gè)文件夾到另一處。
CreateFolder：創(chuàng)建一個(gè)新的文件夾。
CreateTextFile：創(chuàng)建一個(gè)文本文件并返回一個(gè)TextStream對(duì)象用來(lái)讀寫所創(chuàng)建的文本文件。
DeleteFile：刪除一個(gè)或多個(gè)指定的文件。
DeleteFolder：刪除一個(gè)或多個(gè)指定的文件夾。
DriveExists：檢查指定的驅(qū)動(dòng)器是否存在。
FileExists：檢查指定的文件是否存在。
FolderExists：檢查指定的文件夾是否存在。
GetAbsolutePathName：返回指定路徑的完整路徑。
GetBaseName：返回指定文件或文件夾的基本名。
GetDrive：返回指定路徑的在驅(qū)動(dòng)器的相應(yīng)Drive對(duì)象。
GetDriveName：返回指定路徑的驅(qū)動(dòng)器名。
GetExtensionName：返回指定路徑中最后部分的文件擴(kuò)展名。
GetFile：返回一個(gè)關(guān)于指定路徑的文件對(duì)象。
GetFileName：返回指定路徑中最后部分的文件名或文件夾名。
GetFolder：返回一個(gè)關(guān)于指定路徑的文件夾對(duì)象。
GetParentFolderName：返回指定路徑中最后部分的父文件夾名。
GetSpecialFolder：返回Windows某個(gè)專門文件夾的路徑。
GetTempName：返回一個(gè)隨機(jī)生成的臨時(shí)文件或文件夾。
MoveFile：將一個(gè)或多個(gè)文件從一個(gè)地方移動(dòng)到另一地方。
MoveFolder：將一個(gè)或多個(gè)文件從一個(gè)地方移動(dòng)到另一地方。
OpenTextFile：打開一個(gè)文件并返回一個(gè)TextStream對(duì)象用來(lái)讀寫所打開的文件。

BuildPath方法

BuildPath方法為已存在的路徑增加一個(gè)名字。

一、語(yǔ)法

[newpath=]FileSystemObject.BuildPath(path,name)
參數(shù)說(shuō)明：
path：必須的。路徑。
name：所要增加的名字。

二、例子

<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.BuildPath("c:\mydocuments","test")
response.write(path)
set fs=nothing
%>

輸出:

c:\mydocuments\test

CopyFile方法

CopyFile方法從一處復(fù)制一個(gè)或多個(gè)文件到另一處。

一、語(yǔ)法
FileSystemObject.CopyFile source,destination[,overwrite]
參數(shù)說(shuō)明：
source：必須的。所要復(fù)制的文件。
destination：必須的。復(fù)制到的目的地。
overwrite：可選的。是個(gè)布爾值，它指出是否覆蓋已存在的文件。True表示覆蓋，F(xiàn)alse表示不覆蓋。默認(rèn)為True 。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFile "c:\mydocuments\web\*.htm","c:\webpages\"
set fs=nothing
%>

CopyFolder方法

CopyFolder方法一處復(fù)制一個(gè)或多個(gè)文件到另一處。

一、語(yǔ)法
FileSystemObject.CopyFolder source,destination[,overwrite]
參數(shù)說(shuō)明：
source：必須的。所要復(fù)制的文件夾。
destination：必須的。復(fù)制到的目的地。
overwrite：可選的。是個(gè)布爾值，它指出是否覆蓋已存在的文件。True表示覆蓋，F(xiàn)alse表示不覆蓋。默認(rèn)為True 。

二、例子

<%
'copy all the folders in c:\mydocuments\web
'to the folder c:\webpages

dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFolder "c:\mydocuments\web\*","c:\webpages\"
set fs=nothing
%>

<%
'copy only the folder test from c:\mydocuments\web
'to the folder c:\webpages

dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFolder "c:\mydocuments\web\test","c:\webpages\"
set fs=nothing
%>

CreateFolder方法

CreateFolder方法創(chuàng)建一個(gè)新的文件夾。

一、語(yǔ)法

FileSystemObject.CreateFolder(name)
參數(shù)說(shuō)明：
name：必須的。要?jiǎng)?chuàng)建的文件夾的名字。

二、例子

<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.CreateFolder("c:\asp")
set f=nothing
set fs=nothing
%>

CreateTextFile方法

CreateTextFile方法在當(dāng)前文件夾下創(chuàng)建一個(gè)新的文本文件，并返回一個(gè)TextStream對(duì)象用來(lái)讀寫這個(gè)新的文件。

一、語(yǔ)法

FileSystemObject.CreateTextFile(filename[,overwrite[,unicode]])
FolderObject.CreateTextFile(filename[,overwrite[,unicode]])
參數(shù)說(shuō)明：
filename：必須的。所要?jiǎng)?chuàng)建的文件的名字。
overwrite：可選的。是一布爾值，以指出是否覆蓋已存在的文件。True表示覆蓋，F(xiàn)alse表示不覆蓋。默認(rèn)為True 。
unicode：可選的。為一布爾值，指出所創(chuàng)建的文件是Unicode文件還是ASCII文件。True為Unicode文件，F(xiàn)alse為ASCII文件。默認(rèn)是False。

二、例子

FileSystemObject的例子：

<%
dim fs,tfile
set fs=Server.CreateObject("Scripting.FileSystemObject")
set tfile=fs.CreateTextFile("c:\somefile.txt")
tfile.WriteLine("Hello World!")
tfile.close
set tfile=nothing
set fs=nothing
%>

Folder對(duì)象的例子：

<%
dim fs,fo,tfile
Set fs=Server.CreateObject("Scripting.FileSystemObject") 
Set fo=fs.GetFolder("c:\test") 
Set tfile=fo.CreateTextFile("test.txt",false) 
tfile.WriteLine("Hello World!")
tfile.Close
set tfile=nothing
set fo=nothing
set fs=nothing
%>

DeleteFile方法

DeleteFile方法刪除一個(gè)或多個(gè)指定的文件。
注意：如果試圖刪除不存在的文件將會(huì)發(fā)生錯(cuò)誤。

一、語(yǔ)法

FileSystemObject.DeleteFile(filename[,force])
參數(shù)說(shuō)明：
filename：必須的。所要?jiǎng)h除的文件的名字。
force：可選的。一個(gè)布爾值，以表示是否刪除只讀文件。True為是，F(xiàn)alse為否。默認(rèn)是False。

二、例子

<%
dim fs
Set fs=Server.CreateObject("Scripting.FileSystemObject") 
fs.CreateTextFile("c:\test.txt",True)
if fs.FileExists("c:\test.txt") then
  fs.DeleteFile("c:\test.txt")
end if
set fs=nothing
%>

DeleteFolder方法

DeleteFolder方法DeleteFile方法刪除一個(gè)或多個(gè)指定的文件夾。
注意：如果試圖刪除不存在的文件夾將會(huì)發(fā)生錯(cuò)誤。

一、語(yǔ)法

FileSystemObject.DeleteFolder(foldername[,force])
參數(shù)說(shuō)明：
foldername：必須的。所要?jiǎng)h除的文件的名字。
force：可選的。一個(gè)布爾值，以表示是否刪除只讀文件夾。True為是，F(xiàn)alse為否。默認(rèn)是False。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.FolderExists("c:\temp") then
  fs.DeleteFolder("c:\temp")
end if
set fs=nothing
%>

DriveExists方法

DriveExists方法返回一個(gè)布爾值表明指定的驅(qū)動(dòng)器是否存在。True為存在，F(xiàn)alse為否。

一、語(yǔ)法
FileSystemObject.DriveExists(drive)
參數(shù)說(shuō)明：
drive：必須的。一個(gè)驅(qū)動(dòng)器符或一完整的路徑描述。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.DriveExists("c:")=true then
   response.write("Drive c: exists!")
else
  response.write("Drive c: does not exist.")
end If
set fs=nothing
%>

FileExists方法

FileExists方法返回一個(gè)布爾值表明指定的文件是否存在。True為存在，F(xiàn)alse為否。

一、語(yǔ)法
FileSystemObject.FileExists(filename)
參數(shù)說(shuō)明：
filename：必須的。所要檢查的文件的名字。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.FileExists("c:\asp\introduction.asp")=true then
  response.write("File c:\asp\introduction.asp exists!")
else
   response.write("File c:\asp\introduction.asp does not exist!")
end if
set fs=nothing
%>

FolderExists方法
FolderExists方法返回一個(gè)布爾值表明指定的文件夾是否存在。True為存在，F(xiàn)alse為否。

一、語(yǔ)法

FileSystemObject.FolderExists(foldername)
參數(shù)說(shuō)明：
foldername：必須的。所要檢查的文件夾的名字。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
if fs.FolderExists("c:\asp")=true then
  response.write("Folder c:\asp exists!")
else
  response.write("Folder c:\asp does not exist!")
end if
set fs=nothing
%>

GetAbsolutePathName方法
GetAbsolutePathName方法返回關(guān)于指定路徑的完整路徑（將指定路徑轉(zhuǎn)換為絕對(duì)路徑）。

一、語(yǔ)法
FileSystemObject.GetAbsolutePathName(path)
參數(shù)說(shuō)明：
path：必須的。要轉(zhuǎn)換為絕對(duì)路徑的路徑。

二、例子
假設(shè)當(dāng)前目錄是 c:\temp\test: 
例1

<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.GetAbsolutePathName("c:")
response.write(path)
%>

輸出:

c:\temp\test

例 2

<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.GetAbsolutePathName("mydoc.txt")
response.write(path)
%>

輸出:

c:\temp\test\mydoc.txt

例 3

<%
dim fs,path
set fs=Server.CreateObject("Scripting.FileSystemObject")
path=fs.GetAbsolutePathName("private\mydoc.txt")
response.write(path)
%>

輸出:

c:\temp\test\private\mydoc.txt

GetBaseName方法

GetBaseName方法返回指定路徑中文件或文件夾的基本名。

一、語(yǔ)法
FileSystemObject.GetBaseName(path)
參數(shù)說(shuō)明：
path：必須的。文件或文件夾的路徑。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
Response.Write(fs.GetBaseName("c:\winnt\cursors\3dgarro.cur"))
set fs=nothing
%>

輸出:

3dgarro

GetDrive方法

GetDrive方法返回一個(gè)由drivespec參數(shù)指定的Drive對(duì)象。

一、語(yǔ)法
FileSystemObject.GetDrive(drivespec)
參數(shù)說(shuō)明：
drivespec：必須的?？梢允且粋€(gè)驅(qū)動(dòng)器符©，或后跟冒號(hào)的驅(qū)動(dòng)器符(c:)，或后跟冒號(hào)和路徑分隔符的驅(qū)動(dòng)器符(c:\)，或網(wǎng)絡(luò)共享說(shuō)明(\\computer2\share1)。

二、例子

<%
dim fs,d
set fs=Server.CreateObject("Scripting.FileSystemObject")
set d=fs.GetDrive("c:\")
set fs=nothing
%>

GetDriveName方法

GetDriveName方法返回一個(gè)包含指定路徑的驅(qū)動(dòng)器的名字的字符串。

一、語(yǔ)法
FileSystemObject.GetDriveName(path)
參數(shù)說(shuō)明：
path：必須的。指定的路徑。

二、例子

<%
dim fs,dname
set fs=Server.CreateObject("Scripting.FileSystemObject")
dname=fs.GetDriveName("c:\test\test.htm")
Response.Write(dname)
set fs=nothing
%>

輸出:

c:

GetExtensionName方法

GetExtensionName方法返回一個(gè)包含指定路徑中最后部分的文件的文件擴(kuò)展名的字符串。

一、語(yǔ)法
FileSystemObject.GetExtensionName(path)
參數(shù)說(shuō)明：
path：必須的。指定的路徑。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
Response.Write(fs.GetExtensionName("c:\test\test.htm"))
set fs=nothing
%>

輸出:

htm

GetFile方法

GetFile方法返回關(guān)于指定路徑的一個(gè)File對(duì)象。

一、語(yǔ)法
FileSystemObject.GetFile(path)
參數(shù)說(shuō)明：
path：必須的。關(guān)于特定文件的路徑。

二、例子

<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.GetFile("c:\test\test.htm")
Response.Write("The file was last modified on: ")
Response.Write(f.DateLastModified)
set f=nothing
set fs=nothing
%>

輸出:

The file was last modified on 01/01/20 4:23:56 AM

GetFileName方法

GetFileName方法返回一個(gè)包含指定路徑中最后部分的文件或文件夾的名字的字符串。

一、語(yǔ)法
FileSystemObject.GetFileName(path)
參數(shù)說(shuō)明：
path：必須的。關(guān)于特定文件或文件夾的路徑。

二、例子

<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
p=fs.getfilename("c:\test\test.htm")
response.write(p)
set fs=nothing
%>

輸出:

test.htm

<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
p=fs.getfilename("c:\test\")
response.write(p)
set fs=nothing
%>

輸出:

test

GetFolder方法

GetFolder方法返回關(guān)于指定路徑的一個(gè)Folder對(duì)象。

一、語(yǔ)法
FileSystemObject.GetFolder(path)
參數(shù)說(shuō)明：
path：必須的。關(guān)于一特定文件夾的路徑。

二、例子

<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.GetFolder("c:\test\")
Response.Write("The folder was last modified on: ")
Response.Write(f.DateLastModified)
set f=nothing
set fs=nothing
%>

輸出:

The folder was last modified on 01/01/20 4:23:56 AM

GetParentFolderName方法

GetParentFolderName方法返回指定路徑中最后部分的父文件夾的名字。

一、語(yǔ)法

FileSystemObject.GetParentFolderName(path)
參數(shù)說(shuō)明：
path：必須的。要返回其父文件夾名字的文件或文件夾的路徑。

二、例子

<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
p=fs.GetParentFolderName("c:\winnt\cursors\3dgarro.cur")
Response.Write(p)
set fs=nothing
%>

輸出:

c:\winnt\cursors

GetSpecialFolder方法

GetSpecialFolder方法返回關(guān)于某Windows特定文件夾的路徑。

一、語(yǔ)法
FileSystemObject.GetSpecialFolder(foldername) 
參數(shù)說(shuō)明：
foldername：必須的。
foldername取值說(shuō)明：
0=WindowsFolder（包含被windows操作系統(tǒng)安裝的文件）；
1=SystemFolder（包含庫(kù)、字體和設(shè)備驅(qū)動(dòng)程序）
2=TemporaryFolder（用來(lái)存儲(chǔ)臨時(shí)文件）

二、例子

<%
dim fs,p
set fs=Server.CreateObject("Scripting.FileSystemObject")
set p=fs.GetSpecialFolder(1)
Response.Write(p)
set p=nothing
set fs=nothing
%>

輸出:

C:\WINNT\system32

GetTempName方法

GetTempName方法返回一個(gè)隨機(jī)生成的臨時(shí)文件或文件夾。

一、語(yǔ)法

FileSystemObject.GetTempName

二、例子

<%
dim fs,tfolder,tname, tfile
Set fs=Server.CreateObject("Scripting.FileSystemObject") 
Set tfolder=fs.GetSpecialFolder(2)
tname=fs.GetTempName
Set tfile=tfolder.CreateTextFile(tname) 
Response.write (tfile)
%>

輸出:

trb2007.tmp

MoveFile方法

MoveFile方法把一個(gè)或多個(gè)文件從一處移動(dòng)到另一處。

一、語(yǔ)法
FileSystemObject.MoveFile source,destination
參數(shù)說(shuō)明：
source：必須的。要被移動(dòng)的文件的路徑。
destination：必須的。所要移動(dòng)到的位置。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.MoveFile "c:\web\*.gif","c:\images\"
set fs=nothing
%>

MoveFolder方法

MoveFolder方法把一個(gè)或多個(gè)文件夾從一處移動(dòng)到另一處。

一、語(yǔ)法
FileSystemObject.MoveFolder source,destination
參數(shù)說(shuō)明：
source：必須的。要被移動(dòng)的文件夾的路徑。
destination：必須的。所要移動(dòng)到的位置。

二、例子

<%
dim fs
set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.MoveFolder "c:\test\web\","c:\windows\"
set fs=nothing
%>

OpenTextFile方法

OpenTextFile方法打開一個(gè)指定的文件并返回一個(gè)TextStream對(duì)象以用來(lái)訪問(wèn)這個(gè)文件。

一、語(yǔ)法
FileSystemObject.OpenTextFile(fname,mode,create,format)
參數(shù)說(shuō)明：
fname：必須的。要打開的文件的名字。
mode：可選的。以什么方式打開。1=ForReading（以只讀方式打開），2=ForWriting （以寫方式打開），8=ForAppending（以添加方式打開，寫入的內(nèi)容將添加到文件末尾）。
create：可選的。設(shè)置如果所打開的文件不存在是否創(chuàng)建該文件。True為是，F(xiàn)alse為否。默認(rèn)是False。
format：可選的。文件的格式。0=TristateFalse（以ASCII格式打開，這是默認(rèn)的），-1=TristateTrue（以Unicode格式打開），-2=TristateUseDefault （以系統(tǒng)默認(rèn)方式打開）

二、例子

<%
dim fs,f
set fs=Server.CreateObject("Scripting.FileSystemObject")
set f=fs.OpenTextFile(Server.MapPath("testread.txt"),8,true)
f.WriteLine("This text will be added to the end of file")
f.Close
set f=Nothing
set fs=Nothing
%>  

Property

屬性 Description
描述 
Attributes 
Sets or returns the attributes of a specified file
設(shè)置或返回指定文件的屬性 
DateCreated 
Returns the date and time when a specified file was created
返回指定文件建立的日期和時(shí)間 
DateLastAccessed
Returns the date and time when a specified file was last accessed
返回指定文件最后被訪問(wèn)的日期和時(shí)間 
DateLastModified
Returns the date and time when a specified file was last modified
返回指定文件最后被修改的日期和時(shí)間 
Drive
 Returns the drive letter of the drive where a specified file or folder resides
返回指定文件或文件夾所處的盤符的盤符號(hào) 
Name
 Sets or returns the name of a specified file
設(shè)置或返回指定文件的名字 
ParentFolder
 Returns the folder object for the parent of the specified file
返回指定文件的父文件夾 
Path 
Returns the path for a specified file
返回一個(gè)指定文件的路徑 
ShortName
 Returns the short name of a specified file (the 8.3 naming convention)
返回一個(gè)指定文件的短名 (根據(jù)8.3 命名規(guī)則) 
ShortPath
 Returns the short path of a specified file (the 8.3 naming convention)
返回一個(gè)指定文件的短路徑 (根據(jù)8.3 命名規(guī)則) 
Size
 Returns the size, in bytes, of a specified file
返回指定文件所包含的字節(jié)數(shù) 
Type
 Returns the type of a specified file
返回指定文件的類型

Methods
方法
Method
方法 Description
描述 
Copy
Copies a specified file from one location to another
將本機(jī)上的文件復(fù)制到異地機(jī)子上 
Delete Deletes a specified file
刪除指定文件 
Move
Moves a specified file from one location to another
將本機(jī)上的文件移動(dòng)到異地機(jī)子上 
OpenAsTextStream
Opens a specified file and returns a TextStream object to access the file
打開指定文件返回一個(gè)TextStream對(duì)象

這篇文章就介紹到這了，建議繼續(xù)查看下面的相關(guān)文章就行深入學(xué)習(xí)。