批處理（bat）實現(xiàn)全盤搜索指定文件獲取其完整路徑方法大全

來源：本站原創(chuàng)|時間：2020-01-10|欄目：DOS/BAT|點擊：次

廢話不多說，直接上代碼，額，想用的話，自己保存成bat文件即可。

【方案一】for /f + dir

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
      )
    )
  )
)

【方案二】for /r（比 for /f + dir 效率高，但不會遍歷隱藏文件）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    pushd %%a:\
    for /r %%b in (*%FileName%) do (
      if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
      )
    )
    popd
  )
)

【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精簡版可能不支持）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in ("%FileName%") do (
  set "nName=%%~na"
  set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
  echo,%%a
)

【方案四】使用 Windows7 系統(tǒng)自帶的 where 命令

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，請稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo,%%b
      )
    )
  )
)

上一篇：MSG命令使用詳解

欄目：DOS/BAT

下一篇：批處理bat根據(jù)星期啟動程序

本文標題：批處理（bat）實現(xiàn)全盤搜索指定文件獲取其完整路徑方法大全

本文地址：http://mengdiqiu.com.cn/a1/DOS_BAT/10148.html

更多DOS/BAT

欧美大屁股bbbbxxxx,狼人大香伊蕉国产www亚洲,男ji大巴进入女人的视频小说,男人把ji大巴放进女人免费视频,免费情侣作爱视频

DOS/BAT

批處理（bat）實現(xiàn)全盤搜索指定文件獲取其完整路徑方法大全

您可能感興趣的文章

閱讀排行

本欄相關(guān)

隨機閱讀